flyinweb's blog

脚本中心
计算机管理示例脚本
该页面里包含一些脚本，这些脚本通常适用于在Windows 2000, Windows XP, and Windows Server 2003中进行激活、配置、重命名等操作。可以更方便的帮助IT专业人员管理计算机。


更改计算机帐号属性

描述

演示如何通过脚本来更改 Active Directory 中的计算机帐号的位置属性。

脚本代码

Set objComputer = GetObject _  
    ("LDAP://CN=atl-dc-01,CN=Computers,DC=fabrikam,DC=com")  
objComputer.Put "location", "Building 37, Floor 2, Room 2133" 
objComputer.SetInfo 

离线激活 Windows

描述

使用离线方法来激活 Windows。需要 Windows XP 或 Windows Server 2003、以及一个有效的激活编号。

脚本代码

strComputer = "." 
Set objWMIService = GetObject("winmgmts:" & _  
    "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set colWindowsProducts = objWMIService.ExecQuery _  
    ("SELECT * FROM Win32_WindowsProductActivation")  
For Each objWindowsProduct In colWindowsProducts  
    objWindowsProduct.ActivateOffline("1234-1234")  
Next 

在线激活 Windows

描述

使用在线方法来激活 Windows。需要 Windows XP 或 Windows Server 2003、以及活动的 Internet 连接。

脚本代码

strComputer = "." 
Set objWMIService = GetObject("winmgmts:" & _  
    "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set colWindowsProducts = objWMIService.ExecQuery _  
    ("SELECT * FROM Win32_WindowsProductActivation")  
For Each objWindowsProduct In colWindowsProducts  
    objWindowsProduct.ActivateOnline()  
Next 

配置系统启动延时

描述

将计算机配置为在启动时自动加载默认操作系统之前等待 10 秒钟（而不是默认的 30 秒钟）。

脚本代码

strComputer = "." 
Set objWMIService = GetObject("winmgmts:" & _  
    "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set colStartupCommands = objWMIService.ExecQuery _  
    ("SELECT * FROM Win32_ComputerSystem")  
For Each objStartupCommand In colStartupCommands  
    objStartupCommand.SystemStartupDelay = 10  
    objStartupCommand.Put_  
Next 

配置 WMI 设置

描述

配置 WMI 备份时间间隔和日志记录级别。

脚本代码

strComputer = "."   
Set objWMIService = GetObject("winmgmts:" & _   
    "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")   
Set colWMISettings = objWMIService.ExecQuery _   
    ("SELECT * FROM Win32_WMISetting")   
For Each objWMISetting In colWMISettings   
    objWMISetting.BackupInterval = 60   
    objWMISetting.LoggingLevel = 2   
    objWMISetting.Put_   
Next 

获取操作系统属性

描述信息

获取有关计算机上所安装的操作系统信息，其中包括语言种类、加密级别和内建编号等。

脚本代码

Set dtmConvertedDate = CreateObject("WbemScripting.SWbemDateTime")  
strComputer = "." 
Set objWMIService = GetObject("winmgmts:" _  
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set colOperatingSystems = objWMIService.ExecQuery _  
    ("Select * from Win32_OperatingSystem")  
For Each objOperatingSystem in colOperatingSystems  
    Wscript.Echo "Boot Device: " & objOperatingSystem.BootDevice  
    Wscript.Echo "Build Number: " & objOperatingSystem.BuildNumber  
    Wscript.Echo "Build Type: " & objOperatingSystem.BuildType  
    Wscript.Echo "Caption: " & objOperatingSystem.Caption  
    Wscript.Echo "Code Set: " & objOperatingSystem.CodeSet  
    Wscript.Echo "Country Code: " & objOperatingSystem.CountryCode  
    Wscript.Echo "Debug: " & objOperatingSystem.Debug  
    Wscript.Echo "Encryption Level: " & objOperatingSystem.EncryptionLevel  
    dtmConvertedDate.Value = objOperatingSystem.InstallDate  
    dtmInstallDate = dtmConvertedDate.GetVarDate  
    Wscript.Echo "Install Date: " & dtmInstallDate   
    Wscript.Echo "Licensed Users: " & _  
        objOperatingSystem.NumberOfLicensedUsers  
    Wscript.Echo "Organization: " & objOperatingSystem.Organization  
    Wscript.Echo "OS Language: " & objOperatingSystem.OSLanguage  
    Wscript.Echo "OS Product Suite: " & objOperatingSystem.OSProductSuite  
    Wscript.Echo "OS Type: " & objOperatingSystem.OSType  
    Wscript.Echo "Primary: " & objOperatingSystem.Primary  
    Wscript.Echo "Registered User: " & objOperatingSystem.RegisteredUser  
    Wscript.Echo "Serial Number: " & objOperatingSystem.SerialNumber  
    Wscript.Echo "Version: " & objOperatingSystem.Version  
Next 

复制Active Directory计算机帐号

描述信息

获取现有计算机对象属性，并将这些属性复制到通过脚本创建的新增计算机对象中。

脚本代码

Set objCompt = GetObject("LDAP://cn=Computers,dc=NA,dc=fabrikam,dc=com")  
Set objComptCopy = objCompt.Create("computer", "cn=SEA-SQL-01")  
objComptCopy.Put "sAMAccountName", "sea-sql-01" 
objComptCopy.SetInfo  
Set objComptTemplate = _  
  GetObject("LDAP://cn=SEA-PM-01,cn=Computers,dc=NA,dc=fabrikam,dc=com")  
arrAttributes = Array("description", "location")  
For Each strAttrib in arrAttributes  
  strValue = objComptTemplate.Get(strAttrib)  
  objComptCopy.Put strAttrib, strValue  
Next 
objComptCopy.SetInfo 

执行计算机对象的跨域迁移

描述信息

利用 IADsContainer 中的 MoveHere 方法将对象迁移到其他域中。

脚本代码

Set objOU = GetObject("LDAP://cn=Computers,dc=NA,dc=fabrikam,dc=com")  
objOU.MoveHere "LDAP://cn=Computer01,cn=Users,dc=fabrikam,dc=com", _  
 vbNullString 

执行系统还原

描述信息

在计算机上使用系统还原点 No. 20 来执行系统还原。要使用不同的系统还原点来执行系统还原，则只需更改 RESTORE_POINT 常量值即可。

有关在这段脚本中使用的 CreateRestorePoint 方法的更多信息，单击此处。

支持平台

Windows Server 2003
 否
 
Windows XP
 是
 
Windows 2000
 否
 
Windows NT 4.0
 否
 

脚本代码

Const RESTORE_POINT = 20  
strComputer = "." 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\default")  
Set objItem = objWMIService.Get("SystemRestore")  
errResults = objItem.Restore(RESTORE_POINT)  
Wscript.Echo errResults